package require Itcl
namespace import itcl::*

set comment { # A neat way of doing a block comment in Tcl!
Incr-Tcl is an excellent Object Oriented Extension to Tcl,
with all the usual OO facilities supported. This example
pulls many of the various elements together in a single short
demonstration.

You MAY have an incr-Tcl executable on your system, or you may
need to load the extra facilities in as a package - see above.
If you load as a package, then this is an excellent use of a
        namespace import
since you really won't want to be writing itcl::class each time
you define a class, will you?

}

# Here's an example of a base class:

class getabout {
        variable operator
        public variable miles
        method getopo {} {
                return "$operator !!!!! "
                }

        }

# A class that inherits from that base class:

class dublintram {
        inherit getabout
        constructor {whom} { set operator $whom}
        method getprice {} {return 0}
}

# A second class that inherits from that base class:

class pts {
        inherit getabout
        variable departure
        variable reliability
        variable pencepermile
constructor {opo time rel ppm {mls 0}} {
        set operator $opo
        set departure $time
        set reliability $rel
        set pencepermile $ppm
        set miles $mls
        }
method getprice {} {
        return [expr $miles * $pencepermile]
        }
method getpencepermile {} {
        return $pencepermile
        }
method setpencepermile {newval} {
        set pencepermile $newval
        }
}

# MAIN CODE -------------------

# Some slightly contrived code to set up a series of
# objects - in a real application, we would probably
# have a loop reading from a file of database here!

set c 1
pts place$c "East Midlands" 07:00 80 24 40
incr c
pts place$c "First Great Western" 07:17 50 21 25
incr c
dublintram place$c Connex
incr c
pts place$c FGW 07:45 98 56 94

# Note that each of our objects has a name that's made up
# of a pattern - place1 place2 place3 etc, which will allow
# us to iterate through them later

# A demonstration of running a method on an object (to set a value)
# Note that creating an object was created a command of that same name

place2 setpencepermile 50

# Loop though and report on all the objects:

for {set k 1} {$k <= $c} {incr k} {

        # Run a method to get the price
        # This method is polymorphic - one for each class
        # and the code will run the APPROPRIATE method each time
        set costshim [place$k getprice]

        # Run a method to get the operator.
        # This method is the same each time - it has been
        # inherited in each case from the base class
        set runby [place$k getopo]

        # All itcl objects support configure and cget subcommands
        # cget allows you to read any public variables without having
        # to provide an accessor method for every one of them, and
        # configure lets you set the public variables without a method.
        set rb [place$k cget -miles]

        puts "$runby place$k - $costshim $rb"
        }