#!/usr/bin/env expect

# This was originally written as a sample script to show
# how expect can be used on a web server to monitor other
# systems. We've extended it as a live script on our
# own web sites - this is the version that is live at the
# time of writing

set hosts {www.wellho.net
    www.wellho.co.uk
    www.sheepbingo.co.uk
    office.wellho.net
    www.melkshamhotel.co.uk
    www.savethetrain.org.uk
    www.wellhousemanor.co.uk
    www.wellho.info
    www.training-notes.co.uk}

set clients {www.avairpros.com
    www.express-cleaning-supplies.co.uk
    www.gregpullen.co.uk}

set localhosts {hugo fire coffee dolphin pepsi
    saturn mars}

set trainees {tormentil tansy thyme parsley nutmeg flipper
    chopsuey bhajee vindaloo snowdrop
    buttercup elderberry daisy dandelion pasanda foxglove
    }

# If running on our Intranet, test local and client systems instead

if {[regexp {192\.168\.200|127\.0\.0} $env(SERVER_ADDR)]} {
    set hosts [concat $clients $localhosts $trainees]
    }

log_user 0
set timeout 25
set runningcount 0

# Parallel ping all the systems we're testing

foreach system $hosts {
    spawn ping -c 2 $system
    lappend idlist $spawn_id
    set realhost($spawn_id) $system
    incr runningcount
    }

# gather up a series of responses

while {$runningcount > 0} {

expect {
    -i $idlist "\n" {
        set which $expect_out(spawn_id)
        lappend ans($which) $expect_out(buffer)
        }
    eof {
        # search and remove completed host from idlist
        set donepos [lsearch $idlist $expect_out(spawn_id)]
        set idlist [lreplace $idlist $donepos $donepos]
        incr runningcount -1
        }
    timeout {
        break
        }
    }

}

puts "content-type: text/html\n"
set goodstuff ""
set badstuff ""
set good 0
set bad 0

foreach which [array names ans] {
    set posthost 0
    set host "NULL"
    set count 0
    foreach line $ans($which) {
        if {$posthost == 1} {
            set count "undef"
            regexp "\(\[0-9\]\) packets received" $line all count
            # puts "$host - returned $count packets"
            set posthost 2
            }
        if {[regexp ^---\ \(\[^\ \]+\) $line all host]} {
            set posthost 1
            }
        }
    if {$count == 2} {
    append goodstuff "<a href=http://$realhost($which)>"
    append goodstuff "$realhost($which)</a> is available<br>"
    incr good
    } else {
    append badstuff "$realhost($which) is NOT available<br>"
    incr bad
    }
}

set stuff {<span class=subhead><b>System report -
Well House Consultants</b></span></br><br>
<span class=body>Report generated }
append stuff [clock format [clock seconds]]
append stuff {<br><br>}
append stuff "<!-- start -->"
append stuff "<i>Operational ...</i><br>$goodstuff<br><br>"
append stuff "Total of $good systems<hr>"
append stuff "<i><b>Not operational ...</b></i><br>"
append stuff "$badstuff<br><br>Total of $bad systems"
append stuff "<br><!-- end -->"
append stuff {
<br><br>This page is generated by a script written in Expect
(an extension of the Tcl language) and was written by Well
House Consultants who provide <a href=/course/tcl-tk.html>
training on Tcl, Expect and Tk</a>. To learn a
little more about this script, please visit the associated
<a href=/resources/pinginfo.html>information page</a><br>
}

set fh [open template/page.htp r]
set content [read $fh]

regsub %ginc% $content "" content
regsub %cookie% $content "" content
regsub %seepic% $content "" content
regsub %finish% $content "" content
regsub -all %lhs% $content "ctco" content
regsub %topimg% $content "WHhead2.gif" content

regsub %stuff% $content $stuff content
regsub -all %title% $content "Well House System Status" content

regsub -all {<\?php[^\n]*locate[^\n]*?\?>} $content \
        "international site" content
regsub -all {<\?php[^\n]*voiceline[^\n]*?\?>} $content \
        "+44 (0) 1225 708225" content
regsub -all {<\?php[^\n]*today[^\n]*?\?>} $content \
        [clock format [clock seconds]] content
regsub -all {<\?php[^\n]*faxline[^\n]*?\?>} $content \
        "+44 (0) 1225 707126" content
regsub -all {<\?php[^\n]*copyyear[^\n]*?\?>} $content \
        "2005" content
regsub -all {<\?php.*?\?>} $content "" content

puts $content