# Data reformatting example / course end tie together

# the input format ...
# 30,11,2015 EL 8
# 1,12,2015 EP 8
# 14,12,2015 YL 8

# required format
# Code,StartDate,StartTime,EndDate,EndTime,EventType,ID,MasterID,Location,Language,CoursePrice,EventPrice,Currency,Vendor,Title,Category
# LPFULL,07/09/2015,09:00,11/09/2015,17:00,Standard,1,1,SN12 7NY,En-GB,1350,1350,GBP,Well House,Learning to Program in Perl,Other (IT)Code

# Requirement to reformat our diary into a format required by a course reseller

# command to read data into a list of courses
proc loadDataWH {source tab} {
        upvar $tab table
        set fh [open $source r]
        while {! [eof $fh] } {
                gets $fh lyne
                if {[string length $lyne] < 1} continue ; # eliminate blank lines
                lappend table "$lyne"
        }
        close $fh
}

# Command to take that list of courses and output it in the required format
proc saveDataQA {destiny tab} {
        upvar $tab table
        set fh [open $destiny w]
        set template {%2sFULL,%02d/%02d/%4d,09:00,%02d/%02d/%4d,17:00,Standard,1,1,SN12 7NY,En-GB,%d,%d,GBP,Well House,%s,Other (IT)}
        puts $fh "Code,StartDate,StartTime,EndDate,EndTime,EventType,ID,MasterID,Location,Language,CoursePrice,EventPrice,Currency,Vendor,Title,Category"

        foreach course $table {
                regexp {(\d+),(\d+),(\d+)\s+(([A-Z])[A-Z])} $course match day month year coursecode language

                set courselength 5
                set courseformat {Learning to Program in %s}
                if {[regexp {P$} $coursecode]} {
                        set courselength 4
                        set courseformat {%s Programming}
                }

                switch $language {
                        E {set lname Perl}
                        H {set lname PHP}
                        U {set lname Lua}
                        R {set lname Ruby}
                        Y {set lname Python}
                        D {set lname C++}
                        T {set lname Tcl}
                        default {set lname Dunno}}

                set descript [format $courseformat $lname]
                set price [expr 100 + $courselength * 250]

                set starts [clock scan "$day,$month,$year 12 00" -format "%d,%m,%Y %H %M"]
                set ends [expr $starts + ($courselength -1) * 3600 * 24]

                set eday [clock format $ends -format %e]
                set emonth [clock format $ends -format %m]
                set eyear [clock format $ends -format %Y]

                set record [format $template $coursecode $day $month $year $eday $emonth $eyear $price $price $descript]
                puts $fh $record
        }
        close $fh
}

loadDataWH "diary" intoHere
saveDataQA "qa.csv" intoHere