# List basics in a nutshell

# Different ways of setting up a list
# (each of these contains three members)

set party "{Ann Marie} Brenda Charles"
set party "\"Ann Marie\" Brenda Charles"
set party {"Ann Marie" Brenda Charles}
set party "Ann\\ Marie Brenda Charles"
set party {Ann\ Marie Brenda Charles}
set party [list "Ann Marie" Brucella Charlie]

# Append adds a string (so no space)
# but lappend adds a list member (so spaced and protected)
append party Brown
lappend party Douggie

puts $party
# That prints:
# {Ann Marie} Brucella CharlieBrown Douggie

# How long is the "party" variable?
puts [string length $party]
puts [llength $party]
# It's one list. Or a list with 4 indexed members. Or a string of 42 characters

# What's the first item?
set first [lindex $party 0]
puts $first

# What's the last item?
set last [lindex $party [expr [llength $party] -1 ]]
puts $last
# surely there must be an easier way of doing that!
set last [lindex $party end]
puts $last

# Here we are looping through each item of the list
# in this example, we do NOT want to keep track of the position number
foreach person $party {
        puts "Invite $person to the party"
        }

# Here we are looping through each item of the list
# in this example, we DO want to keep track of the position number
for {set count 0} {$count < [llength $party]} {incr count} {
        set name [lindex $party $count]
        puts "I expect person $count will come (that's $name )"
        }

exit

# ---------------------------------------------------

munchkin:n13tcl grahamellis$ tclsh liimp
{Ann Marie} Brucella CharlieBrown Douggie
41
4
Ann Marie
Douggie
Douggie
Invite Ann Marie to the party
Invite Brucella to the party
Invite CharlieBrown to the party
Invite Douggie to the party
I expect person 0 will come (that's Ann Marie )
I expect person 1 will come (that's Brucella )
I expect person 2 will come (that's CharlieBrown )
I expect person 3 will come (that's Douggie )
munchkin:n13tcl grahamellis$