#!/usr/bin/env tclsh
# Finding distances between places base on OS grid references

# Read in the OS big grid table

set fh [open os_letters.txt r]
while {[gets $fh lyne] > 0} {
        regsub "#.*" $lyne "" result
        if {[string length $result] < 1} continue
        lappend squares $result
        }

# Find out about your journey - e.g. ST899646 SU149853 TQ265814

puts -nonewline "What are the grid reference on your journey (space separated?) "
flush stdout
gets stdin osrefs

# Work out the true north and east value of each point
# (This would be much easier using arrays - later on the course!)

foreach osref $osrefs {
                # Need to trap erroneous formats in the user's grid refs!
        set letters [string range $osref 0 1]
                # Scan to sort out issues with leading zeros on easting / northing
        scan [string range $osref 2 4] %d east
        scan [string range $osref 5 end] %d north
        set mega_north 0
        foreach band $squares {
                if {[set mega_east [lsearch $band $letters]] > -1} break
                incr mega_north
                }
        set easting [expr 1000 * $mega_east + $east]
        set northing [expr 1000 * $mega_north + $north]
        lappend elist $easting
        lappend nlist $northing
        }

# And work out the length of each leg

for {set to 1} {$to < [llength $elist]} {incr to} {
        set from [expr $to - 1]
        set east_west [expr [lindex $elist $from] - [lindex $elist $to]]
        set north_south [expr [lindex $nlist $from] - [lindex $nlist $to]]
        set leg_distance [format %.1f [expr 0.1 * hypot($east_west, $north_south)]]
        puts $leg_distance
        }

# Sample results
#
# munchkin:survey grahamellis$ tclsh distance_between
# What are the grid reference on your journey (space separated?) ST899646 SU149853 TQ265814
# 32.46
# 111.67
# munchkin:survey grahamellis$