use strict;

{ package trainjourney;
our @ISA = ("journey");
sub getroute {
        my ($current) = @_;
        return "By train from ". $current->{from} . " to " . $$current{to};
        }

# SUPER looks for method in parent class via the ISA route
# Here's an example - "I want to do what the base class does with an extra bit"
sub getarrival {
        my ($current) = shift;
        my $excuse = $current->SUPER::getarrival(@_);
        return "$excuse ... but LATE!\n";
        }
}

{ package busjourney;
our @ISA = ("journey");
sub getroute {
        my ($current) = @_;
        return "By bus from ". $current->{from} . " to " . $$current{to};
        }
        }

{ package journey;
sub new {
        my ($class,$from,$to,$deptime,$mins,$capa) = @_;
        my %info;
        $info{from} = $from;
        $info{to} = $to;
        $info{deptime} = $deptime;
        $info{mins} = $mins;
        $info{capa} = $capa;
        bless \%info,$class; }

# Melksham Devizes 08:40 16 81 road
# factory method

sub build {
        my ($properties) = @_;
        my ($from, $to, $deptime, $mins, $capa, $mode) = split(/\s+/,$properties);
        if ($mode eq "rail") {
                return (new trainjourney($from, $to, $deptime, $mins, $capa)); }
        elsif ($mode eq "road") {
                return (new busjourney($from, $to, $deptime, $mins, $capa));
        }
        die "Data is screwed up - $properties\n";
        }

sub getarrival {
        my ($current) = @_;
        my $result = $$current{deptime} . "+" . $$current{mins};
        return $result; }

sub getroute {
        my ($current) = @_;
        # On "from" and "to" - different syntax for same type of access!
        return $current->{from} . " to " . $$current{to};
        }
sub longer {
        my ($this,$that) = @_;
        ( $this->getmins() > $that->getmins() ) ? $this : $that;
        }

sub longest {
        my ($sofar,@maybes) = @_;
        foreach my $tryme (@maybes) {
                $sofar = $sofar->longer($tryme);
                }
        $sofar;
        }

sub get {
        my ($current,$prop) = @_;
        return $current->{$prop};
        }

sub set {
        my ($current,@others) = @_;
        my $fp = $others[0];
        my %params;
        if (ref($fp) eq "HASH") {
                %params = %$fp;
} else {

        die ("That's odd") if (@others % 2);
        %params = @others;
        }
        foreach my $k (keys(%params)) {
                my $k9 = $k;
                $k9 =~ s/^-//;
                $current->{$k9} = $params{$k};
                }
        return 1;
        }

sub AUTOLOAD {
        my ($current,@others) = @_;
        our $AUTOLOAD; # like a "no strict" for the one variable!
        # contents are ... journey::getfrom ... or similar!

        my ($key,$property) = $AUTOLOAD =~ /.*:(...)(.*)/;

        if ($key eq "get") {
                return $current->{$property};
                }

        if ($key eq "set") {
                return $current->{$property} = $_[1];
                }
        }
}

no strict;
push @options, new trainjourney("Melksham","Trowbridge","06:40",12,150);
push @options, new busjourney("Melksham","Bath","07:12",42,61);
push @options, new trainjourney("Melksham","Swindon","07:17",25,75);
push @options, new busjourney("Melksham","London","07:45",150,81);
push @options, new busjourney("Melksham","Easterton","19:25",35,53);

$source = <<DONE;
Melksham Devizes 08:40 16 81 road
Melksham Calne 14:10 18 61 road
Melksham Cheltenham 19:47 63 140 rail
Melksham Southampton 19:11 83 150 rail
DONE

@extras = split(/\n/,$source); # represents data from a file!
# factory method - will build me an object of some type or other!!
foreach $addition (@extras) {
        push @options,journey::build($addition);
        }

$options[4] -> set(comment => "near to home", -from => "Bowerhill", deptime => "19:29", mins => 31);

%lundun = ("from","Sells Green","to","Victoria");
$options[3] -> set(\%lundun);

foreach $j (@options) {
        print "Leaving from ",$j->getfrom()," and going to ",$j->getto(),"\n";
        print $j->getroute()," arrives at ",$j->getarrival(),"\n";
        print $j->getmins(),"\n";
        print $j->get("comment"),"\n\n";
        }

$dis = $options[0];
$dat = $options[1];

sub handle {
        my ($obj) = @_;
        print "How about a trip to ",$obj->getto(),"\n";
        }

# ugle psuedo-code ... handle the longer one
# if ($dis->longer($dat)) {
# handle($dis);
# } else {
# handle($dat); }

# Better - handle the longer ("most appropriate") one
# These are dynamic (object) methods running on a class MEMBER (passing in another)

$approp = $dis->longer($dat);
handle($approp);
$approp = $dat->longer($dis);
handle($approp);

# This is a static (class) methods running in the class AS A WHOLE
# (we can't be sure that there's a member to run it on and we want symmetry in the list)

$approp = journey::longest(@options);
handle($approp);

__END__

Sample data

wizard:pl graham$ perl oo6
Leaving from Melksham and going to Trowbridge
By train from Melksham to Trowbridge arrives at 06:40+12 ... but LATE!

12

Leaving from Melksham and going to Bath
By bus from Melksham to Bath arrives at 07:12+42
42

Leaving from Melksham and going to Swindon
By train from Melksham to Swindon arrives at 07:17+25 ... but LATE!

25

Leaving from Sells Green and going to Victoria
By bus from Sells Green to Victoria arrives at 07:45+150
150

Leaving from Bowerhill and going to Easterton
By bus from Bowerhill to Easterton arrives at 19:29+31
31
near to home

Leaving from Melksham and going to Devizes
By bus from Melksham to Devizes arrives at 08:40+16
16

Leaving from Melksham and going to Calne
By bus from Melksham to Calne arrives at 14:10+18
18

Leaving from Melksham and going to Cheltenham
By train from Melksham to Cheltenham arrives at 19:47+63 ... but LATE!

63

Leaving from Melksham and going to Southampton
By train from Melksham to Southampton arrives at 19:11+83 ... but LATE!

83

How about a trip to Bath
How about a trip to Bath
How about a trip to Victoria
wizard:pl graham$