=head1 Looking for commonality in lists

One of the questions that's cropped up on our forums and in my emails many times over the
years reads something like "I have a number of arrays and I want to get the common values in
them".

Here is a Perl program which provides a number of helpful guidances towards an answer to
what is actually a very poorly defined question - do you want to find things that occur in
all the incoming lists, or in more than one list? Are you looking for things which are at
the same position in each list ... etc

=cut

use Data::Dumper;

# Set up some sample data

@first = qw(cat dog hamster tortoise snake lizard);
@second = qw(mouse cat dog cow horse shark);
@third = qw(cow sheep goat dog snake cat rabbit rabbit rabbit);

# Display the data as part of the demo

@lol = (\@first, \@second, \@third);
print Dumper(\@lol);

# Count the number of different lists that contain each item

foreach $sl (@lol) {
        $ilists++;
# %unique is used to avoid double-counting items that occur several times in the same list
        my %unique;
        foreach $item (@$sl) {
                $counter{$item}++ unless $unique{$item};
                $unique{$item} = 1;
        }
# at this point %unique goes out of scope and so is reset for the next outer loop iteration
}

# Various reports

@commons = grep($counter{$_} == $ilists,keys(%counter));
print ("In all lists - @commons\n");

@several = grep($counter{$_} > 1,keys(%counter));
print ("In several lists - @several\n");

@unique = grep($counter{$_} == 1,keys(%counter));
print ("In just one list - @unique\n");

__END__

Sample output:

wizard:nov10 graham$ perl clutter
$VAR1 = [
          [
            'cat',
            'dog',
            'hamster',
            'tortoise',
            'snake',
            'lizard'
          ],
          [
            'mouse',
            'cat',
            'dog',
            'cow',
            'horse',
            'shark'
          ],
          [
            'cow',
            'sheep',
            'goat',
            'dog',
            'snake',
            'cat',
            'rabbit',
            'rabbit',
            'rabbit'
          ]
        ];
In all lists - cat dog
In several lists - snake cat cow dog
In just one list - tortoise lizard horse shark rabbit hamster sheep mouse goat
wizard:nov10 graham$